Chip 1998 July/Chip_1998-07_cd.bin/zkuste/mazda/mazIn311.dxr/Internal_19_Image Cycle Cast Members.ls

Text File | 1998-05-06 | 3.9 KB | 89 lines

property enabled, membermin, membermax, ImageCastLib, MemberRefMin, MemberRefMax, CycleStyle, goingDown, currentstate, numstates, name

on CycleState me, name
  if name = the name of me then
    bumpstate_intern(me)
  end if
end

on setstate me, statenum
  if the enabled of me then
    if statenum > the numstates of me then
      set statenum to the numstates of me
    else
      if statenum < 1 then
        set statenum to 1
      end if
    end if
    set the member of sprite the spriteNum of me to member (the membermin of me + statenum - 1) of castLib ImageCastLib
  end if
end

on setgoingDown me, value
  set the goingDown of me to value
end

on SetCycleStyle me, value
  set the CycleStyle of me to value
end

on bumpstate_intern me
  if the enabled of me then
    if the CycleStyle of me = #repeat then
      if not (the goingDown of me) then
        set curr to the currentstate of me + 1
        if curr > the numstates of me then
          set curr to 1
        end if
      else
        set curr to the currentstate of me - 1
        if curr < 1 then
          set curr to the numstates of me
        end if
      end if
    else
      if not (the goingDown of me) then
        set curr to the currentstate of me + 1
        if curr > the numstates of me then
          set curr to curr - 2
          set the goingDown of me to 1
        end if
      else
        set curr to the currentstate of me - 1
        if curr < 1 then
          set curr to 2
          set the goingDown of me to 0
        end if
      end if
    end if
    set the currentstate of me to curr
    setstate(me, curr)
  end if
end

on beginSprite me
  set the enabled of me to 1
  set the membermin of me to the memberNum of member MemberRefMin
  set the membermax of me to the memberNum of member MemberRefMax
  set the numstates of me to the membermax of me - the membermin of me + 1
  set the currentstate of me to the memberNum of sprite the spriteNum of me - the membermin of me + 1
  set the ImageCastLib of me to the number of castLib the castLibNum of sprite the spriteNum of me
  setstate(me, the currentstate of me)
end

on getPropertyDescriptionList
  if the currentSpriteNum = 0 then
    set memdefault to 0
  else
    set memref to the member of sprite the currentSpriteNum
    set castLibNum to the castLibNum of memref
    set memdefault to member (the memberNum of member memref + 1) of castLib castLibNum
  end if
  set p_list to [#name: [#comment: "Item Name:", #format: #symbol, #default: #MultiState_1], #MemberRefMin: [#comment: "First Image:", #format: #graphic, #default: memref], #MemberRefMax: [#comment: "Last Image:", #format: #graphic, #default: memdefault], #CycleStyle: [#comment: "Cycle Style:", #format: #symbol, #range: [#repeat, #Reverse], #default: #repeat], #goingDown: [#comment: "Reverse Order:", #format: #boolean, #default: 0]]
  return p_list
end

on getBehaviorDescription
  return "Makes the sprite cycle through a range of cast members when the CycleState message is received." & RETURN & "PARAMETERS:" & RETURN & "ΓÇó Item Name - (optional) Enter an item name to identify the current sprite so that it can receive a specific message. Do not use spaces. Use the name as an argument for the Message Sprite or Message All Sprites behaviors." & RETURN & "ΓÇó First Image - Enter the name of the first cast member in the cycling range." & RETURN & "ΓÇó Last Image  - Enter the name of the last cast member in the cycling range." & RETURN & "ΓÇó Cycle Mode - Choose Repeat to repeat the same sequence.  Choose Reverse to cycle back through the sequence in reverse order." & RETURN & "ΓÇó Reverse Order - Turn this option on to proceed from the last to the first image by default." & RETURN & "MESSAGES:" & RETURN & "ΓÇó CycleState - Switches the sprite's cast member to the next image in the sequence." & RETURN & "ΓÇó SetState state_number - Advances directly to the position in the sequence identified by state_number."
end